HTML

Zsebszámológép programok, forráskódok, hírek

Egy blog zsebszámológép programokról, algoritmusokról, érdekességekről.

Játék

Szabadon letölthető, megújult Gazdálkodj okosan! stratégiai társasjáték szabállyal együtt.

Friss topikok

Linkblog

Kokárda Casio CFX-9850GB Plus grafikus számológépen

2011.03.14. 16:29 Sany80

Az alábbi, kevesebb mint 200 bájtos program kokárdát rajzol Casio CFX-9850GB Plus programozható grafikus zsebszámológépen.

(a képernyőkép ide kattintva tekinthető meg)

Prog "KOKARDA"

ViewWindow 6,24,0,10,20,0

For 0->A To 4

0.13A -> B

Orange Circle 15,16,1+B

Green Circle 15,16,2.4+B

Orange F-Line 14.6-B, 13, 13.4-B,10

Orange F-Line 15.4+B, 13, 16.6+B,10

Green F-Line 13.8-B, 14, 12-B, 10

Green F-Line 16.2+B, 14, 18+B,10

Next

Szólj hozzá!

Címkék: casio basic forráskód

Egy érdekes programozás feladat

2011.01.11. 07:11 Sany80

Egy érdekes (de azért nem túl bonyolult) programozási feladat:

Keresünk 4 db olyan 4 jegyű, egymás után következő számot, melyek oszthatóak a jegyeik összegével (a feladat a HPmuseum.org fórumán jelent meg, és a Számológép Fórumon is szóba került).

Saját, Casio Basic nyelvű megoldásom:

{1,1,1,1 -> List 1;
For 1-> A To 9
For 0-> B To 9
For 0-> C To 9
For 0-> D To 9
   List 1[2 -> List 1[1
   List 1[3 -> List 1[2
   List 1[4 -> List 1[3
   1000A + 100B + 10C + D -> N
   A+B+C+D -> S
   Frac(N / S -> List 1[4
   If 0 = Max(List 1
   Then N - 3 ki
   N - 2 ki
   N - 1 ki
   N ki
   IfEnd
Next
Next
Next
Next

Szólj hozzá!

Címkék: casio basic feladat

A Basic programozás alapjai

2010.11.29. 07:58 Sany80

A Basic nyelvű programozás alapjai - a Casio FX-7500P programozható tudományos számológép programozási nyelvén szemléltetve a Számológép Fórum egyik topikjában.

A Casio FX-7500P érdekessége, hogy programnyelve erősen különbözik a későbbi grafikus Casio-k Basic-jétől, mivel formula-programozási elemket is tartalmaz.

Szólj hozzá!

Címkék: fórum casio basic

Kaprekar-féle szám generáló program Casio FX-7400G-re

2010.10.04. 07:14 Sany80

A Kaprekar-féle számról: http://en.wikipedia.org/wiki/Kaprekar_number

Topik a Számológép Fórumon: http://groups.google.hu/group/szamologep/browse_thread/thread/f70fd12fab1573e

 ? -> A
{0,0,0,0 -> List 1
For 1 -> B To 4
Frac (A / 10)*10 -> List 1[5 - B
Int (A / 10 -> A
Next

For 1 -> B To 3
For 1 -> C To B
If List 1[C] < List 1[C+1
Then List 1[C -> S
List 1[C+1 -> List 1[C
S -> List 1[C+1
IfEnd
Next
Next

999*List 1[1] + 90*List 1[2] - 90*List 1[3] - 999*List 1[4] (output)

Szólj hozzá!

Címkék: casio basic forráskód kaprekar

Egy bizonyos "ABCDE" prímszám keresése - Casio FX-7400G-vel

2010.07.26. 07:54 Sany80

Feladat a HPmuseum.org fórumáról, amellyel a Számológép Fórumon is külön topik foglalkozik:

Keresünk egy olyan ötjegyű, P =  ABCDE prímszámot, melyre igaz, hogy P = A! + B! + C! + D! + E! + A + B + C + D + E.

Megoldás Casio FX-7400G programozható grafikus zsebszámológépre:

Prog "FELADAT"
ClrText
0 -> I
{1,3,7 -> List 2
For 1 -> A To 8
For 0 -> B To 8
For 0 -> C To 8
For 0 -> D To 8
For 1 -> K To 3
List 2[K] -> E
9999A + 999B + 99C + 9D = A! + B! + C! + D! + E!
=> Prog "PRIMKER"
Next
Next
Next
Next
Next

Prog "PRIMKER"
"OSSZEG OK"
I + 1 -> I
10000A + 1000B + 100C + 10D + E -> P
1 -> M
1 -> T
Lbl 1
M + 1 -> M
Frac (P/M) = 0 => 0 -> T
(T=1)(M<400 => Goto 1
If T = 1
Then "MEGVAN"
P
IfEnd
Return

Szólj hozzá!

Címkék: casio basic grafikus számológép forróskód

Lottószám-generáló program TI-92 grafikus számológépre

2010.07.20. 11:48 Sany80

Lottószám-generáló TI-Basic program Texas Instruments TI-92 programozható grafikus zsebszámológépre.

d darab véletlenszámot generál 1 és m között, majd rendezi is azokat (lottó-szaknyelven: "növekvő számsorrendbe").

lotto(m,d)
Prgm
{0} -> t
For i,1,d
   Lbl a
   rand(m) -> t[i]
   1 -> s
   For j,1,i-1
      If t[i] = t[j]
      0 -> s
   EndFor
   If s = 0 and i > 1
   Goto a
EndFor
SortA t
Disp t
EndPrgm

Szólj hozzá!

Címkék: lottó basic forráskód texas instruments grafikus számológép

Első programjaim HP-28C-re

2010.07.12. 08:55 Sany80

Nem sokkal ezelőtt hozzájutottam egy HP-28C retro programozható grafikus zsebszámológéphez, íme az első néhány programom, RPL nyelven:

1. példa: Hang lejátszás BEEP utasítással, ciklussal, 100-tól 2000-es frekvenciákon, 100-as lépésközzel:

<< 0 100 2000 FOR I I .2 BEEP 100 STEP >>

2. példa: Véletlenszerű pontok a kijelzőre:

<< CLLCD
(0,0) PMIN
(1,1) PMAX
1 100 FOR I
RAND 'A' STO
RAND 'B' STO
A B R->C PIXEL
NEXT >>

3. példa: Pixel-sűrűséges "átmenet" a kijelzőn:

<< CLLCD
(0,0) PMIN
(1,1) PMAX
1 10000 FOR I
RAND 'A' STO
RAND 'B' STO
IF RAND A > AND RAND A >
THEN A B R->C PIXEL
END
NEXT >>

 

Szólj hozzá!

Címkék: retro program forráskód hewlett packard grafikus számológép rpl

Simon memóriajáték program Casio grafikus számológépre

2010.05.24. 14:37 Sany80

Az ismert Simon memóriajáték, mindössze 395 byte-on.

Írta: Csetneki Sándor

képernyőkép a játékról

21 -> Dim List 1;
ClrText;
Locate 3,1,"SIMON MEMORY GAME";
For 1 -> X To 21;
Locate X,2,"-";
Next;
0 -> A;
Lbl 1;
Isz A;
Locate 1,3,"SIMON SAYS:     ";
1 + Int 4 Ran# -> List 1[A;
Locate A,4,List 1[A;
For 1 -> X To 21;
Locate X,5,".";
Next;
Locate 1,3,"WHAT SAID SIMON?";
For 4 -> Y To 5;
Locate 1,Y,"                      ";
Next;
1 -> M;
Lbl G;
Do;
Getkey -> Z;
LpWhile Z = 0;
For 1 -> X To 20: Next;
(Z=72) + 2(Z=62) + 3(Z=52) + 4(Z=73 -> T;
T = 0 => Goto G;
Locate M,4,T;
T = List 1[M -> N;
Isz M;
N(M<=A => Goto G;
N => Goto 1;
Locate 1,5,"GAME OVER! SCORE:";
Locate 19,5,A-1;
For 1 -> X To A;
Locate X,6,List 1[X;
Next

Szólj hozzá!

Címkék: játék memória program simon casio

RPN értelmező program

2010.05.10. 06:15 Sany80

Casio Basic program, mely lehetővé teszi az RPN (reverse polish notation - fordított lengyel jelölés) adatbevitelt, és végrehajtja a számítást. Három részprogramból áll: RPN a főprogram (ez végzi a kezdőképernyő megjelenítését és a lenyomott billentyűk beolvasását, és meghívja a másik két programot), RPNTRANS alprogram, amely a bevitt billentyű-kódokból kialakít egyfajta RPN mátrixot, az RPNCALC pedig a számítást végzi el. A programon még lehet szépíteni, alakítgatni, ez egy kezdetleges (de már működőképes) változat. A 3 program mérete együtt alig több 1 kilobyte-nál.

Írta: Csetneki Sándor

képernyőkép

Prog "RPN"

Lbl 0;
ClrText;
For 1 -> A To 40: Next;
Locate 1,1,"-- CASIO BASIC RPN --";
Locate 1,7,"F1: CALC F5: CLR F6: DEL";
21 -> Dim List 1;
1 -> A;

Lbl 1;
Do;
Getkey -> B;
LpWhile B = 0;
10 -> W;

If B = 31;
Then Locate A,3,":";
 -7 -> W;
IfEnd;

If B = 61;
Then Locate A,3,".";
 -6 -> W;
IfEnd;

If B = 41;
Then Locate A,3,"-";
 -5 -> W;
IfEnd;

If B = 42;
Then Locate A,3,"+";
 -1 -> W;
IfEnd;

If B = 32;
Then Locate A,3,"-";
 -2 -> W;
IfEnd;

If B = 43;
Then Locate A,3,"x";
 -3 -> W;
IfEnd;

If B = 33;
Then Locate A,3,"/";
 -4 -> W;
IfEnd;

B = 71 => 0 -> W;
B = 72 => 1 -> W;
B = 62 => 2 -> W;
B = 52 => 3 -> W;
B = 73 => 4 -> W;
B = 63 => 5 -> W;
B = 53 => 6 -> W;
B = 74 => 7 -> W;
B = 64 => 8 -> W;
B = 54 => 9 -> W;

W >= 0 And W <= 9 => Locate A,3,W;

If W != 10
Then W -> List 1[A;
A+1 -> A;
IfEnd;

*********** teljes törlés ***********

B = 39 => Goto 0;

*********** törlés ***********
If B = 29
Then A > 1 => A-1 -> A;
Locate A,3," ";
IfEnd;

*********** számítás ***********


If B = 79


Then -8 -> List 1[A;


Prog "RPNTRANS";


Prog "RPNCALC";


Locate 1,5,"RESULT:     ";


Locate 9,5,List 2[1;


IfEnd;


Goto 1;

 

RPNTRANS program:

{30,2 -> Dim Mat A;
{30,2 -> Dim Mat B;
1 -> X;
0 -> V;
0 -> T;
1 -> E;
0 -> I;

While List 1[X] != -8;
List 1[X -> B;
X+1 -> X;
B>=0 And B<=9 And T=0 => 10*V+B -> V;

If B>=0 And B<= 9 And T=1;
Then V+WB -> V;
.1W -> W;
IfEnd;

If B= -5;
Then -1 -> E;
IfEnd;

If B= -6;
Then 1 -> T;
0.1 -> W;
IfEnd;

If B<0 And B!= -8 And B!= -6 And B!= -5
Then I+1 -> I;
E*V -> Mat A[I,1;
1 -> Mat A[I,2;
0 -> V;
0 -> T;
1 -> E;
I+1 -> I;

If B >= -4 And B <= -1


Then Abs B -> Mat A[I,1;


0 -> Mat A[I,2;


IfEnd;


IfEnd;


WhileEnd;


I+1 -> I;


3 -> Mat A[I,1;


3 -> Mat A[I,2;


1 -> I;


1 -> J;


While Mat A[I,2]!=3;


Mat A[I,1 -> B;


Mat A[I,2 -> C;


If A!=0 And B!=0


Then B -> Mat B[J,1;


C-> Mat B[J,2;


J+1 ->J;


IfEnd;


I+1 -> I;


WhileEnd;


3 -> Mat B[J,2;


Mat B -> Mat A

RPNCALC

30 -> Dim List 2;
1 -> X;
While Mat A[X,2] != 3;
Mat A[X,1 -> B;
Mat A[X,2 -> C;
X+1 ->X;

If C = 1
Then List 2[5 -> List 2[6;
List 2[4 -> List 2[5;
List 2[3 -> List 2[4;
List 2[2 -> List 2[3;
List 2[1 -> List 2[2;
B -> List 2[1;
IfEnd;

If C = 0


Then List 2[2 -> M;


List 2[1 -> N;


B=1 => M+N -> D;


B=2 => M-N -> D;


B=3 => M*N -> D;


B=4 => M/N -> D;


List 2[3 -> List 2[2;


List 2[4 -> List 2[3;


List 2[5 -> List 2[4;


List 2[6 -> List 2[5;


D -> List 2[1;


IfEnd;


WhileEnd

Szólj hozzá!

Címkék: casio számológép grafikus basic rpn

Sierpinski háromszög Casio és TI grafikus számológépen

2010.04.27. 07:28 Sany80

Egy híres (és szép) fraktál, a Sierpinski háromszög Casio és Texas Instruments grafikus számológépekre (képernyőképet és további információkat itt találsz).

A meglepően rövid forráskód (Casio Basic):

ViewWindow 0,2,0,0,1,0;
Ran# -> A;
Ran# -> B;
{0,1,2 -> List 1;
{0,1,0 -> List 2;
For 1 -> J To 10.000;
1 + int( 3 * Ran# -> C;
0.5*(A + List 1[C] -> A;
0.5*(A + List 2[C] -> B;
Plot A,B;
Plot A,B;
Next;

és a TI Basic forráskód:

:ClrDraw
:0→Xmin:2→Xmax
:0→Ymin:1→Ymax
:rand→A:rand→B
:{0,1,2→L₁
:{0,1,0→L₂
:Repeat getKey
:randInt(1,3→C
:mean({A,L₁(C→A
:mean({B,L₂(C→B
:Pt-On(A,B
:End

 

 

 

Szólj hozzá!

Rekurzív algoritmus Casio grafikus számológépen

2010.04.19. 08:48 Sany80

A klasszikus rekurzív algoritmus példa Casio programozható grafikus számológépen: faktoriális számítás. Két programból áll, a Factrun-nal kell indítani, a Fact pedig maga a rekurzív szubrutin, amely önmagát hívja meg. Sajnos csak 10 mélységig működik, utána "Ne Error" hibaüzenetet ad (legfeljebb 10 mély lehet a rekurzió a Casio számológépeken).

Még több  példaprogram található a Számológép Fórumon.

 

Program "FACTRUN"
"FACT"? -> N;
1 -> F;
Prog "FACT";

Program "FACT"
F x N -> F;
N - 1 -> N;
If N > 1;
Then Prog "FACT";
Else print: F;
IfEnd;

Szólj hozzá!

Címkék: program casio számológép rekurzió grafikus basic

Átmenetes pi szimbólum Casio grafikus számológépen

2010.03.21. 16:23 Sany80

Program, amely "átmenetes" pi-szimbólumot állít elő véletlenszámokkal.

Szerző: Csetneki Sándor

A képernyőkép megtekintéséhez kattints ide.

Prog "PIART"

ClrGraph;

ViewWindow 0,1.75,0,0,1,0;

0 -> P;

For 1 -> M To 22500;

1.75Ran# -> X;

Ran# -> Y;

1 -> S;

(X>.25)(X<1.5)(Y>.688)(Y<.937 => 0 -> S;

(X>.5)(X<.75)(Y>.063)(Y<.937 => 0 -> S;

(X>1)(Y<1.25)(Y>.063)(Y<.937 => 0 -> S;

S => Ran#>Y -> B;

S => Ran#>Y -> C;

S => Ran#>Y -> D;

S=0 => Ran#>Y -> B;

S=0 => Ran#>Y -> C;

S=0 => Ran#>Y -> D;

BCD => Plot X,Y;

BCD => Plot X,Y;

BCD => Isz P;

Next;

Szólj hozzá!

Címkék: művészet casio számológép grafikus

Pi közelítés Leibniz-formulával grafikus számológépen

2010.03.20. 15:27 Sany80

Az előző poszt kissé komplikált algoritmusa után következzék egy sokkal egyszerűbb (igaz, sokkal lassabb, és sokkal kevesebb tizedesjegyet előállítani képes) program, amely a Leibniz-formulával közelíti a pi értékét Casio programozható grafikus zsebszámológépeken (pl. Casio CFX-9850 GB Plus-on, vagy Casio FX-7400 G-n).

ClrText;

4 -> P;

3 -> A;

For 1 -> X to X+1;

P-4/A+4/(A+2) -> P;

A+4 -> A;

Locate 8,3,P;

Locate 2,3,X;

Next

Szólj hozzá!

Címkék: pi casio számológép grafikus leibniz

Pi közelítő program Casio grafikus számológépre akár 200 tizedesjegyig

2010.03.20. 14:02 Sany80

Cass Lewart Texas Instrumenst grafikus számológépekre írt pi közelítő (meghatározó) programját átírtam Casio számológépekre.

A forráskód:

255 -> Dim List 1;

255 -> Dim List 2;

"SZAMJEGYEK"? -> N;

N*ln 10 / ln 4 -> S;

1+int(ln(S*S*16)/ln 10 -> M;

M-1 -> E;

E+N -> N;

1 -> C;

While C <= N;

0 -> List 1[C;

0 -> List 2[C;

Isz C;

WhileEnd;

5 -> List 1[2;

5 -> List 2[2;

2 -> G;

1 -> A;

"A KOVETKEZO JEGY....";

While G < N;

A*A -> U;

A+2 -> A;

(A-1)*A*4 -> D;

G -> C;

While C <N;

List 2[C]*U -> List 2[C;

Isz C;

WhileEnd;

G -> C;

0 -> R;

While C<N;

R*10+List 2[C -> R;

While R<D And C<N;

0 -> List 2[C;

Isz C;

R*10 -> List 2[C;

WhileEnd;

Int (R/D -> X;

X -> List 2[C;

R-X*D -> R;

Isz C;

WhileEnd;

While List 2[G]=0 And G<N;

Isz G;

WhileEnd;

G -> C;

While C<=N;

List 2[C]+List 1[C] -> List 1[C;

Isz C;

WhileEnd;

If G<=N-E;

Then Locate 5,5,G;

IfEnd;

WhileEnd;

1 -> C;

While C <N;

List 1[C]*6 -> List 1[C;

Isz C;

WhileEnd;

N -> C;

While C>1;

If List 1[C]>9;

Then List 1[C]/10 -> P;

10 * Frac P -> List 1[C;

List 1[C-1]+Int P -> List 1[C-1;

IfEnd;

C - 1 -> C;

WhileEnd;

0 -> List 1[N;

0 -> List 1[N-1;

0 -> List 1[N-2;

"VEGE"

 

 És egy másik, apró program, ami listázza a pi jegyeit a képernyőn:

ClrText;

Locate 1,1,"3.";

2 -> A;

3 -> X;

1 -> Y;

While A<21*7;

Locate X,Y,List 1[A;

Isz A;

Isz X;

X>21 => Isz Y;

X>21 => 1->X;

WhileEnd;

Locate 2,1,".";

 

 

 

 

 

Szólj hozzá!

Címkék: pi program casio forráskód

Számológép témájú mikroblog: szamologep.tumblr.com

2010.03.20. 13:18 Sany80

Zsebszámológépekkel, kalkulátorokkal kapcsolatos mikroblogot indítottam még december végén a szamologep.tumblr.com címen, ahol érdekes linkek, képek, információk sokaságát találhatod nyers, szerkesztetlen formában. A mikroblog immár több mint 200 bejegyzést tartalmaz.

Szólj hozzá!

Címkék: mikroblog tumblr

Újabb interjúk a Számológép Blogban

2010.01.25. 07:42 Sany80

A számológépek, kalkulátorok iránt érdeklődő kedves közönség újabb érdekes interjúkat olvashat a szamologep.blogspot.com webnapló hasábjain.

Például az ausztrál David L. Jones-szal, aki egy házilag összeszerelhető tudományos számológép kit-et készített. Az óra érdekessége, hogy RPN módban is üzemel, valamint még beépített sakkot is tartalmaz. (Sajnos az óra első szériája már kifutott, de hamarosan érkezik egy még komolyabb változat.)

Aztán olvasható interjú Thierry Planterose-zal is, aki egy francia arc, és Párizsban írja számológépekkel kapcsolatos webnaplóját. És készített egy online számológépet is.

Akinek még ez sem elég, elolvashatja a Sasvári "Angelday" Józseffel készített interjút. Angelday egy ismert hazai blogger, és az iPhone-ok mellett a grafikus számológépek és az RPN irányában is érdeklődést mutat.

Legutóbb pedig Litauszky György (számológép-programozó, TI-92 specialista) válaszolt pár kérdésre.

Jó olvasgatást!

 

Szólj hozzá!

Címkék: interjú számológép grafikus rpn

Érettségire milyen számológépet?

2009.12.04. 11:47 Sany80

Az alábbi bejegyzésből megtudhatod, hogy milyen típusú számológépet lehet használni érettségin és milyet nem, valamint hogy honnan ismerheted fel azokat a számológépeket, melyeket (elvileg) nem szabad használni az érettségi vizsgán.

Egy olvasói levélre reagálva: Számológép és érettségi

Szólj hozzá!

Címkék: érettségi matematika

Interjúk a Számológép Blogban

2009.11.18. 06:16 Sany80

A Számológép Blogban ezentúl interjúk is olvashatóak.

Az első interjút az rskey.org* oldal fenntartójával (és számológép-gyűjtővel), Tóth Viktorral készítettem, a másodikat pedig Nagy Gáborral, aki az egyik legnépszerűbb grafikus számológép alkalmazást készítette iPhone-ra. Az egy dollárba kerülő programot már több mint 70.000 iPhone-tulajdonos vásárolta meg.

Interjú Tóth Viktorral - kiderül például, hogy melyik a kedvenc számológépe, és hogy milyen számológépek, ritkaságok hiányoznak a gyűjteményéből.

Interjú Nagy Gáborral - többek között arra is válaszol Gábor, hogy milyen grafikus számológépei voltak korábban, és hogy tervezi-e RPN üzemmóddal kiegészíteni az alkalmazást.

* Az rskey.org az egyik legnagyobb és leglátogatottabb online számológép adatbázis, ahol elsősorban programozható zsebszámológépekről találhatók információk, adatok, képek.

Szólj hozzá!

Címkék: interjú számológép rskey

Sörrel hajtott számológép

2009.07.09. 09:31 Sany80

Számológép, ami sörrel működik - ráadásul a kijelzőjén pi látható. Sör helyett működtethető vízzel vagy kávéval is.

További információ a sörkedvelő kalkulátorról:

Beer powered calculator

 

2 komment

Címkék: sör kütyü pi számológép

Számológép fülbevaló, pi-vel

2009.06.16. 08:05 Sany80

Egy különleges ékszer: számológép fülbevaló, amelyről a pi értéke olvasható le, 5 tizedesjegyig:

Pi Blog - Pi a számológép fülbevaló kijelzőjén

1 komment

Címkék: pi ékszer fülbevaló

CalcR - parancssoros online számológép

2009.06.05. 09:49 Sany80

Egyszerű, de stílusos parancssoros online számológép, az InstaCalc konyhájából:

CalcR

Szólj hozzá!

Címkék: online számológép parancssor

Emu48 - HP 48 emulátor

2009.05.28. 09:55 Sany80

Nincs Hewlett Packard grafikus RPN számológéped?

Íme az Emu48, a legnépszerűbb HP 48 emulátor, immáron több mint 12 éve. RPN rulez!

http://hp.giesselink.com/emu48.htm

 

Szólj hozzá!

Címkék: emulátor hp hewlett packard rpn grafikus számológép

Egy éves az Avasmath 80 online tudományos számológép

2009.05.28. 07:22 Sany80

Két nap múlva, május 30.-án egy éves lesz az Avasmath 80 online tudományos számológép, az első programozható online számológép. Ez idő alatt több ezren számítások tízezreit végezték el rajta, és az egyik legnépszerűbb online számológép lett a hazai szférában.

Boldog születésnapot, Avasmath 80!

Szólj hozzá!

Címkék: születésnap online tudományos számológép jubileum avasmath

2 az 500. hatványon valamennyi számjegyének kiszámítása grafikus számológépen

2009.04.28. 17:59 Sany80

2 az 500. hatványon az a szám, amelyet úgy kapunk, hogy kettőt megszorozzuk kettővel, majd ismét kettővel - összesen ötszázszor. Így egy 151 jegyű számot kapunk.

Az alábbi program kiszámítja ezt a számot, annak minden számjegyével együtt - de kiszámítható vele akár 2 a 64. hatványon is (amely egy jóval kisebb szám), és a sakk születésének legendájából ismert.

Prog "BIGNUMBR"

ClrText;

"2^N CALCULATION";

"N"?->N;

250->Dim List 1;

1->List 1[250;

0->W;

For 1->B To N;

Locate 18,3,B;

249-.4B->G;

For 250->A To G Step -1;

List 1[A]*2+W->List 1[A;

0->W;

If List 1[A]-10->List 1[A];

1->W;

IfEnd;

Next;

Next;

1->A;

Do;

Isz A;

LpWhile List 1[A]=0;

1->C;

Cls;

2->R;

For A->B To 250;

Text R,4C,List 1[B;

Isz C;

C>30=>R+8->R;

C>30=>1->C;

Next

A programot írta: Csetneki Sándor

Szólj hozzá!

Címkék: program 2 casio 500 számológép grafikus basic hatvány

Véletlenszámokkal előállított "művészi" ábrák, átmenetek Casio grafikus számológépen

2009.04.23. 05:50 Sany80

Gömb, vonal-átmenetek és "spirál" alakú átmenet Casio CFX-9850GB Plus grafikus számológépen. A három program mellett az azok "vetítésére" szolgáló program is megtalálható a bejegyzés végén.

A grafikák előállítása hosszadalmas, akár 10 percig is tarthat a kalkulátoron.

Poszt, képernyőkép és YouTube videó link a programokról

Gömb program

ViewWindow 0,2,0,0,1,0;

For 1->A To 15000;

.5+Ran#->X;

Ran#->Y;

.5>sqrt((X-1)(X-1)+(Y-.5)(Y-.5)->B;

.5>sqrt((X-1)(X-1)+(Y-.5)(Y-.5)->C;

.5>sqrt((X-1)(X-1)+(Y-.5)(Y-.5)->D;

BCD=>Plot X,Y;

BCD=>Plot X,Y;

Next;

Átmenet program

ViewWindow 0,1,0,0,1,0;

For 1->A To 18000;

Ran#->X;

Ran#->Y;

Ran#>X->B;

Ran#>X->C;

0->D;

Y<.25=>1->D;

(Y<.75)(Y>.5)=>1->D;

D=>1-X->X;

BC=>Plot X,Y;

BC=>Plot X,Y;

Next;

Csiga program

ViewWindow 0,2,0,0,1,0;

{.5,.75,1,1.25,1.25,1.25,1.25,1,.75,.5,.5,.5,.75,1,1,.75->List 1;

{.75,.75,.75,.75,.5,.25,0,0,0,0,.25,.5,.5,.5,.25,.25->List 2;

For 1->B To 15;

For 1->C To  B*B*2;

List 1[B]+.25Ran#->X;

List 2[B]+.25Ran#->Y;

Plot X,Y;

Plot X,Y;

Next;

Next;

Vetítő program

(Használatához előtte Pict 1, Pict 2 és Pict 3 képmemóriába el kell menteni a programok futásának végeredményét.)

Cls;

750->B;

For 1->D To 100;

Cls;

RclPict 1;

Plot -1,-1;

For 1->A To B:Next;

Cls;

RclPict 2;

Plot -1,-1;

For 1->A To B:Next;

Cls;

RclPict 3;

Plot -1,-1;

For 1->A To B:Next;

Next;

 

 

1 komment

Címkék: program casio csiga számológép grafikus basic gömb spirál átmenet véletlenszám